FD Calculator in Excel: Maturity Amount and Interest with Quarterly Compounding (Compare 3 Offers)

By Ravindra Bagale · Last updated: 17 October 2026

Download the template: fd-maturity-calculator-template.xlsx: example data with real formulas. Yellow cells are inputs you can type over; green cells hold formulas; blue rows are headers and totals. Replace the example data with your own and everything recalculates.

Made-up data: every name, amount, shop and date on this page is made up for practice. Cities are used only to make the examples feel real.

1. The example

₹1,00,000 for 5 years in three made-up offers:

Offer C has a lower rate than B but pays ₹568 more, because interest is added 12 times a year instead of once. Offer A's figure, ₹1,41,478 for ₹1 lakh at 7% quarterly for 5 years, is the same as the worked example on SBI Securities' FD calculator page. SBI's own maturity calculator also says its interest is compounded quarterly.

The formula. Maturity = P × (1 + r/n)^(n × t), where P is the deposit, r the yearly rate, n the times interest is added per year and t the years. In Excel the same thing is =FV(r/n, n*t, 0, -P).

2. Build it step by step

Step 1. Type the offers

1. In B4:D4 type Offer A, Offer B, Offer C.
2. In A5:A8 type Deposit, Interest rate per year, Years, Compounding.
3. Type the deposit, rate and years in B5:D7 (yellow).
4. Select B8:D8 > Data > Data Validation > List: Monthly,Quarterly,Half-yearly,Yearly (drop-down lists).

Step 2. Times per year

1. In B9 type =IF(B8="Monthly",12,IF(B8="Quarterly",4,IF(B8="Half-yearly",2,1))) (nested IF).
2. Copy B9 right to D9: 4, 1 and 12.

Step 3. Maturity amount

1. In B10 type =ROUND(FV(B6/B9,B9*B7,0,-B5),0): ₹1,41,478.
2. B6/B9 is the rate per compounding period (7%/4 = 1.75% a quarter) and B9*B7 is the number of periods (20 quarters).
3. The 0 means no extra deposits; -B5 is the deposit paid out today. ROUND gives whole rupees (ROUND).
4. Copy right: ₹1,41,901 and ₹1,42,469.

Step 4. Interest and effective yield

1. In B11 type =B10-B5: ₹41,478 interest.
2. In B12 type =(1+B6/B9)^B9-1: 7.19%. This is the rate you really earn in one year after compounding, so offers with different compounding can be compared fairly.

Step 5. Pick the best

1. In B13 type =IF(B10=MAX($B$10:$D$10),"Best","") and copy right. Offer C shows Best.
2. Select B10:D10 > Home > Conditional Formatting > New Rule > Use a formula: =B10=MAX($B$10:$D$10), green fill (formula rules).

Step 6. Year-by-year table

1. In A16:A20 type 1 to 5.
2. In B16 type =ROUND(FV(B$6/B$9,B$9*$A16,0,-B$5),0): ₹1,07,186 after year 1.
3. Copy B16 to B16:D20. The mixed references keep each offer's inputs in rows 5 to 9 and the year in column A.

3. Formulas used

Every formula above is written in the template, so you can click a cell and see it in the formula bar. All values on this page were recalculated in the file.

4. Common mistakes

1. Using the yearly rate for every period. =FV(7%,20,0,-100000) treats 7% as the quarterly rate. Divide by the times per year: 7%/4.
2. Counting years instead of periods. For quarterly compounding, 5 years is 20 periods. Use B9*B7.
3. Comparing only the rate. 7.25% yearly pays less than 7.10% monthly here. Compare the maturity amount or the effective yield.
4. Expecting the receipt to match to the rupee. Banks may add simple interest for a part quarter and round differently, so the receipt can differ by a few rupees.
5. Forgetting the minus sign. Without -B5 FV shows a minus maturity amount.

5. More real examples

Example 1: Monthly-payout FD. If the interest is paid out every month, it does not compound. Monthly interest is then roughly =B5*B6/12; the deposit stays ₹1,00,000.

Example 2: FD ladder. Split ₹3,00,000 into three FDs of 1, 2 and 3 years. Put each in its own column so one matures every year.

Example 3: Recurring deposit vs FD. For a monthly deposit, use FV with a payment: see the SIP calculator for FV with pmt.

Quick revision cards

Englishमराठीहिंदी

Quick revision

Each card shows formulas from this page, each with an example and its answer from the template. Scan the QR code on a card to open this lesson. All names and numbers are made up for practice.

More cards: Ravi Sir's Cards.

6. Frequently asked questions

What is the formula for FD maturity in Excel?

=FV(rate/n, n*years, 0, -deposit), or =deposit*(1+rate/n)^(n*years). For quarterly compounding, n is 4.

How much is ₹1 lakh at 7% for 5 years compounded quarterly?

₹1,41,478, so the interest is ₹41,478.

Which is better: monthly or quarterly compounding?

At the same rate, monthly gives a little more because interest is added more often. Compare the effective yield in row 12.

Can I compare more than three offers?

Yes. Copy column D to E, F and so on, and widen $B$10:$D$10 in the MAX formula.

Is FD interest the same as the final amount?

No. The maturity amount includes your deposit; interest is maturity minus the deposit (row 11).

7. Quick quiz

Ten questions on this page. Sign in to save your score.